ものすごい行数のテキストファイルを開く際にとても時間がかかったりヘタするとエディタが落ちる事もあったのでVBスクリプトでテキストファイルを分割するプログラムを簡単に書きました。また使いたくなることもあるかと思うので載せておきます。

スクリプト

Dim arg
Dim objFSO
Dim objFile
Dim newFile
Dim lineCount
Dim fileNum
Dim num
Dim path

Const splitNum = 10

arg         = WScript.Arguments(0)
Set objFSO  = WScript.CreateObject("Scripting.FileSystemObject")
Set objFile = objFSO.OpenTextFile(arg)

lineCount = 0
fileNum   = 0
path = objFSO.getParentFolderName(WScript.ScriptFullName) & "\"

Do While objFile.AtEndOfStream <> True
	
	num = lineCount Mod splitNum
	
	If num = 0 Then
		
		If lineCount <> 0 Then
			newFile.Close
		End If
		
		fileNum = fileNum + 1
		
		Set newFile = objFSO.CreateTextFile(path & fileNum & ".txt", true)
	End If
	
	lineCount = lineCount + 1
	
	newFile.WriteLine(objFile.ReadLine)
	
Loop

newFile.Close
objFile.Close

Set objFile = Nothing
Set objFSO  = Nothing
Set newFile = Nothing

スクリプトの第一引数に対象ファイルのパスを指定していますので、拡張子vbsで保存しそのスクリプトファイルに対象のファイルをドラッグするだけでOK。ダブルクリックしたらエラーになります。 定数のsplitNumで分割行数を設定していますのでコード上は10行ごとに別のファイルに分割します。お好きな行数にsplitNumを変更してください。拡張子についてもコード中の.txtを適宜csvなどに変えていただけたらそれで分割できます。 分割されたファイルのファイル名は順に1からつけていきます。好みで改造してください。